unction SYS_CREMBX( prmflg, chan : int64 ;
    maxmsg : int64 = 0 ; bufquo : int64 = 0 ; promsk : int64 = 0 ;
    acmode : int64 = 0 ; lognam : int64 = 0 ; flags : int64 = 0 ;
    nullarg : int64 = 0 ) : int64 ;

var Status : int64 ;
    SysRequest : TString1I8_Request ;

begin
    Status := 0 ;
    fillchar( SysRequest, sizeof( SysRequest ), 0 ) ;
    SysRequest.Request.Subsystem :=  UOS_Subsystem_FIP ;
    SysRequest.Request.Request := UOS_FIP_CREMBX ;
    SysRequest.Request.Length := sizeof( SysRequest ) - sizeof( TSystem_Request ) ;
    SysRequest.Request.Status := integer( @Status ) ;
    if( Lognam <> 0 ) then
    begin
        SysRequest.String1.Buffer := PSRB( Lognam )^.Buffer ;
        SysRequest.String1.Length := PSRB( Lognam )^.Length ;
    end ;
    SysRequest.Integer1 := prmflg ;
    SysRequest.Integer2 := chan ;
    SysRequest.Integer3 := maxmsg ;
    SysRequest.Integer4 := bufquo ;
    SysRequest.Integer5 := promsk ;
    SysRequest.Integer6 := acmode ;
    SysRequest.Integer7 := flags ;
    SysRequest.Integer8 := nullarg ;

    Call_To_Ring0( integer( @SysRequest ) ) ;
    Result := Status ;
end ;

        UOS_FIP_CREMBX:
            begin
                UE := Enter_System_Call( Request, SReq, PID, MMC,
                    sizeof( TString1I8_Request ) - sizeof( SReq ), Address ) ;
                if( UE <> nil ) then
                begin
                    Set_Last_Error( UE ) ;
                    exit ;
                end ;
                try
                    String1I8_Request := PString1I8_Request( Address ) ;

                    Status := Create_Mailbox( String1I8_Request.Integer1,
                        String1I8_Request.Integer2, String1I8_Request.Integer3,
                        String1I8_Request.Integer4, String1I8_Request.Integer5,
                        String1I8_Request.Integer6, String1I8_Request.Integer7,
                        String1I8_Request.Integer8, String1I8_Request.String1 ) ;
                    Write_User_int64( Kernel, PID, String1I8_Request.Request.Status,
                        Status ) ;
                finally
                    Exit_System_Call( integer( String1I8_Request ), PID, MMC,
                        sizeof( TString1I8_Request ) - sizeof( SReq ) ) ;
                end ;
            end ;

function TUOS_FiP.Create_Mailbox( prmflg, Handle, MaxMsg, BufQuo, Promsk,
    AcMode, Flags, Reserved : int64 ; Logical_Name : TSRB ) : int64 ;

var MB : TMailbox ;
    Descriptors : array[ 0..1 ] of TSYS_Descriptor ;
    Devname, Name : string ;
    I : integer ;
    PID : TPID ;
    Resource : TMailbox_Resource ;
    S : TUOS_String ;
    Status : int64 ;
    StatusL : longint ;
    SRB1, SRB2, SRB3 : TSRB ;
    Table : string ;

begin
    // Get and validate parameters...
    if( ( prmflg < 0 ) or ( prmflg > 1 ) ) then
    begin
        Result := UOSErr_Invalid_Flags ;
        exit ;
    end ;
    if( Handle = 0 ) then // No address to write handle to
    begin
        Result := UOSErr_Bad_Parameter ;
        exit ;
    end ;
    PID := Kernel.PID ;
    S := Get_User_String( Kernel, PID, Logical_Name, StatusL ) ;
    if( S <> nil ) then
    begin
        Name := S.Contents ;
        S.Free ;
    end ;
    if( MaxMsg = 0 ) then
    begin
        MaxMsg := Kernel.System_Parameters.DEFMBXBUFQUO ;
    end ;
    if( BufQuo = 0 ) then
    begin
        BufQuo := Kernel.System_Parameters.DEFMBXBUFQUO ;
    end ;
    if( AcMode <> 0 ) then
    begin
        BufQuo := Get_User_Integer( Kernel, PID, BufQuo, StatusL ) ;
        if( StatusL <> 0 ) then
        begin
            Result := StatusL ;
            exit ;
        end ;
    end else
    begin
        AcMode := USC.Access_Mode( PID ) ;
    end ;

    // Validate privileges...
    if( Prmflg = 0 ) then // Temporary
    begin
        if( ( USC.Get_Process_Info( PID, JPI_CURPRIV ) and ( TMPMBX or PRMMBX ) ) = 0 ) then
        begin
            Result := UOSErr_Protection_Violation ;
            exit ;
        end ;
        if( USC.Check_Quota( PID, Quota_BYTLM, BufQuo ) ) then
        begin
            Result := UOSErr_Quota_Exceeded ;
            exit ;
        end ;
    end else
    begin
        if( ( USC.Get_Process_Info( PID, JPI_CURPRIV ) and PRMMBX ) = 0 ) then
        begin
            Result := UOSErr_Protection_Violation ;
            exit ;
        end ;
    end ;

    // Create mailbox...
    MB := TMailbox.Create( Kernel ) ;
    MB.Device.Owner.Protections := Promsk ;
    MB.Device.Owner.Owner := USC.Get_Process_Info( PID, JPI_UIC ) ;
    MB.Device.Creator := MB.Device.Owner.Owner ;
    MB.Device.Creation := HAL.Timestamp ;
    MB.Device.Tag := integer( MB ) ;
    MB.Max_Storage := Bufquo ;
    MB.Max_Message := MaxMsg ;
    if( prmflg = 0 ) then // Temporary
    begin
        I := Temporary_Mailboxes.indexof( nil ) ;
        if( I = -1 ) then
        begin
            I := Temporary_Mailboxes.Add( nil ) ;
        end ;
        Temporary_Mailboxes[ I ] := MB ;
        Devname := 'MAILB' ;
    end else
    begin
        I := Permanent_Mailboxes.indexof( nil ) ;
        if( I = -1 ) then
        begin
            I := Permanent_Mailboxes.Add( nil ) ;
        end ;
        Permanent_Mailboxes[ I ] := MB ;
        MB.Permanent := True ;
        Devname := 'MAILA' ;
    end ;
    Devname := '_' + Devname + inttostr( I ) + ':' ;

    // Assign symbol...
    if( Name <> '' ) then
    begin
        fillchar( SRB2, sizeof( SRB2 ), 0 ) ;
        Set_String( 'lnm$system_directory', SRB3 ) ;

        // Make sure symbol name table is defined...
        if( MB.Permanent ) then
        begin
        if( ( USC.Get_Process_Info( PID, JPI_CURPRIV ) and SYSNAM ) = 0 ) then
        begin
            Result := UOSErr_Protection_Violation ;
            exit ;
        end ;
            Table := 'LNM$PERMANENT_MAILBOX' ;
        end else
        begin
            Table := 'LNM$TEMPORARY_MAILBOX' ;
        end ;
        Set_String( Table, SRB1 ) ;
        Result := Kernel.SSC.Create_Symbol_Table( Kernel, PID,
          Pchar( Table ), 'lnm$system_directory', SRB2, 0, LNM_M_CREATE_IF,
          0, PROTECTION_OWNER_MASK or PROTECTION_SYSTEM_MASK or PROTECTION_WORLD_READ, 2 ) ;
        if( Result <> 0 ) then
        begin
            exit ;
        end ;

        // Assign logical equivalent...
        Set_String( Devname, SRB2 ) ;
        fillchar( Descriptors, sizeof( Descriptors ), 0 ) ;
        Descriptors[ 0 ].MBO := $FFFF ;
        Descriptors[ 0 ].MBMO := -1 ;
        Descriptors[ 0 ].Buffer_Length := SRB2.Length ;
        Descriptors[ 0 ].Buffer_Address := SRB2.Buffer ;
        Descriptors[ 0 ].Item_Code := LNM_STRING ;
        Result := Kernel.SSC.Create_Symbol( Kernel, PID, PChar( Name ),
            PChar( Table ), 0, int64( @Descriptors ), 2 ) ;
        if( Result <> 0 ) then
        begin
            exit ;
        end ;
    end ; // if( Name <> '' )

    // Create and assign handle...
    Resource := TMailbox_Resource.Create ;
    Resource._Device := MB.Device ;
    Resource._File := TFile( MB ) ;
    MB.Add_Handle( Resource ) ;
    MB._Name := Devname ;
    USC.Add_Handle( PID, int64( @Resource ) ) ;
    Result := Write_User_int64( Kernel, PID, Handle, int64( @Resource ) ) ;
end ; // TUOS_FiP.Create_Mailbox

type TFile_Resource = class( TResource )
                          public
                              function Write( Stream : longint ; Position : int64 ;
                                  Length : int64 ; Buff : PAnsichar ; Flags : integer ;
                                  var Written : cardinal ) : TUnified_Exception ;
                                  override ;
                      end ;

function TFile_Resource.Write( Stream : longint ; Position : int64 ; Length : int64 ;
    Buff : PAnsichar ; Flags : integer ; var Written : cardinal ) : TUnified_Exception ;

var Len : TStore_Size64 ;

begin
    Len := _File.Write( Stream, Position, Length, Buff[ 0 ], Written ) ;
    Result := _File.Last_Error ;
    if( _File.Is_Store ) then
    begin
        Position := Position + Len ;
    end ;
end ;


type TMailbox_Resource = class( TResource )
                             public
                                 function Write( Stream : longint ; Position : int64 ;
                                     Length : int64 ; Buff : PAnsichar ;
                                     Flags : integer ; 
                                     var Written : cardinal ) : TUnified_Exception ;
                                     override ;
                         end ;

function TMailbox_Resource.Write( Stream : longint ; Position : int64 ;
    Length : int64 ; Buff : PAnsichar ; Flags : integer ;
    var Written : cardinal ) : TUnified_Exception ;

var MB : TMailbox ;

begin
    MB := TMailbox( TDevice( _Device ).Tag ) ;
    Written := MB.Write( 0, 0, Length, Buff[ 0 ], 0 ) ;
    Result := Last_Error ;
    if( Result <> nil ) then
    begin
        exit ;
    end ;
end ;