In the previous article, we documented the shutdown script. In this article, we will look at the script itself. Note that there are several aspects of system shutdown that apply to features which we have yet to address (such as queues). Therefore, you will see multiple TODO comments in the script which take the place of code that we will cover in the future. Also not covered is the actual process of hiberating the system, or cluster-related operations, which are also topics for the future. Now some might ask why shutdown is done with a script rather than with a program. Good question. We are following the VMS specification here, but I'm not entirely sure it matters for UOS. Perhaps there is a good reason for using this approach that I've haven't been able to discern. But in this matter, we will defer to the VMS designers.

$! SHUTDOWN.COM
$! UOS System Shutdown script
$!
$ write sys$output "SHUTDOWN -- Perform an Orderly System Shutdown"
$ if shutdown$time.NES.""
$ then
$     write sys$error "SHUTDOWN-E-ALRDY, System shutdown is already running."
$     write sys$error "Allow it to finish or run OPCCRASH (shutdown$time system symbol is set)"
$     exit
$ endif

$!
$! Initial checks and setup...
$!
$ privs = "AUDIT,CMKRNL,EXQUOTA,LOG_IO,NETMBX,OPER,SECURITY,SYSNAM,SYSPRV,TMPMBX,WORLD"
$ saved_privs = f$setprv(privs)
$ if.NOT.f$privilege(privs)
$ then
$     write sys$error "%SHUTDOWN-F-NOPRIV, the following privileges are required:"
$     write sys$error "-SHUTDOWN-F-NOPRIV, ''privs'"
$     exit
$ endif
$!
$ value = f$trnlnm("SHUTDOWN$NETWORK_MINUTES","LNM$SYSTEM_TABLE")
$ value .nes. ""
$ then
$     NetMin = value
$ else
$     NetMin = 6
$ endif
$ value = f$trnlnm("SHUTDOWN$QUEUE_MINUTES","LNM$SYSTEM_TABLE")
$ if value .nes. ""
$ then
$     QueMin = value
$ else
$     QueMin = 1
$ endif

$!
$! Get override option...
$!
$Start:
$ P1 = f$edit(P1,"LOWERCASE,TRIM,UNCOMMENT")
$ P1 = f$extract(0,1,P1)
$ Minutes = 0
$ Reason = ""
$ SpinDown = "no"
$ SiteShutdown = "yes"
$ Restart = "no"
$ BackUp = "later"
$ AutoStart = 1
$ Default = shudown$disable_autostart
$ if Default.NES."" then AutoStart=Default
$ if P1.EQS."h" goto BeginShutdown
$ if P1.EQS."p" goto BeginShutdown
$ if P1.EQS."r"
$ then
$     Restart = "yes"
$     Backup = "shortly via automatic reboot"
$     goto BeginShutdown
$ endif
$ if P1.NES.""
$ then
$     write sys$error "SHUTDOWN-E-INVOPT, Invalid option.  Must be POWER_OFF, HIBERNATE, or REBOOT"
$     exit
$ endif

$!
$! No override option given, get default values
$!
$AskAgain:
$ Minutes=0
$ Default = f$trnlnm("SHUTDOWN$MINIMUM_MINUTES","LNM$SYSTEM_TABLE")
$ if Default.NES."" then Minutes=Default
$!
$! Query admin for shutdown parameters
$!
$ read/prompt = "How many minutes until final shutdown [''Minutes']: " sys$input Min
$ if Min.EQS."" then Min = Minutes
$ if Min.LT.Minutes
$ then
$     write sys$error "SHUTDOWN-E-TOOSMAL, Minimal allowed minutes until shutdown is ''Minutes'"
$     goto AskAgain
$ endif
$ Minutes = Min

$!
$ read/prompt = "Reason for shutdown [Standalone]: " sys$input Reason
$ Reason = f$edit(Reason,"TRIM")
$ read/prompt = "Do you want to spin down the disk volumes [No]? " sys$input SpinDown
$ SpinDown = f$edit(SpinDown,"LOWERCASE,TRIM,UNCOMMENT")
$ if SpinDown.EQS."" then SpinDown="no"
$ read/prompt = "Do you want to invoke the site-specific shutdown script [Yes]? " sys$input SiteShutdown
$ SiteShutdown = f$edit(SiteShutdown,"LOWERCASE,TRIM,UNCOMMENT")
$ if SiteShutdown.EQS."" then SiteShutdown="yes"
$ read/prompt = "Should an automatic system restart be performed [No]? " sys$input Restart
$ Restart = f$edit(Restart,"LOWERCASE,TRIM,UNCOMMENT")
$ if Restart.EQS."" then Restart="no"
$ read/prompt = "When will the system be rebooted [later]? " sys$input BackUp
$ BackUp = f$edit(BackUp,"TRIM")
$ if BackUp.EQS."" 
$ then 
$     BackUp = "later"
$     if f$extract(0,1,Restart).EQS."y" then BackUp = "shortly via automatic reboot"
$ endif
$AskOptions:
$ write sys$output "Valid shutdown options:"
$ write sys$output "CLUSTER_SHUTDOWN    Entire cluster is being shut down."
$ write sys$output "DISABLE_AUTOSTART=n Disable auto-start queues in n minutes."
$ write sys$output "REBOOT_CHECK        Verify that the system is bootable."
$ write sys$output "REMOVE_NODE         Remaining nodes in the cluster should adjust quorum." 
$ write sys$output "SAVE_FEEDBACK       Save usage characterists for this boot session."
$ read/prompt="Shutdown options [NONE]: " sys$input options
$ options=f$edit(options,"LOWERCASE,TRIM,UNCOMMENT")

$!
$! Parse options
$!
$ ClusterShutdown = ""
$ DisableAutostart = ""
$ RebootCheck = ""
$ RemoveNode = ""
$ SaveFeedback = ""
$OptionLoop:
$! Get next option (comma-delimited)
$ P = f$locate(",",option)
$ ThisOption = f$extract(0,P,option)
$ option = f$extract(P+1,f$length(option),option)
$ if ThisOption.EQS."" then goto OptionLoop
$ if f$extract(0,1,option).EQS."c"
$ then
$     ClusterShutdown = "y"
$ else
$     if f$extract(0,3,ThisOption).EQS."reb"
$     then
$         RebootCheck = "Y"
$     else
$         if f$extract(0,3,ThisOption).EQS."rem"
$         then
$             RemoveNode = "y"
$         else
$             if f$extract(0,1,ThisOption).EQS."s"
$             then
$                 SaveFeedback = "Y"
$             else
$                 if f$extract(0,1,ThisOption).EQS."d"
$                 then
$                     P = f$locate("-",ThisOption)
$                     ThisOption=f$extract(P+1,f$length(ThisOpeion),ThisOption)
$                     if ThisOption.EQS."" then ThisOption = AutoStart
$                     if f$type(ThisOption).NES."INTEGER"
$                     then
$                         write sys$error "SHUTDOWN-E-NOTNUM, Invalid number"
$                         write sys$error "    \''ThisOption'\"
$                         goto AskOptions
$                     endif
$                 else
$                     write sys$error "SHUTDOWN-E-BADOPT, Invalid value for DISABLE_AUTOSTART"
$                     write sys$error "    \''ThisOption'\"
$                     goto AskOptions
$                 endif
$             endif
$         endif
$     endif
$ endif
$ if option.NES."" then goto OptionLoop
$ if f$extract(0,1,RemoveNode).EQS."y"
$ then
$     if f$extract(0,1,ClusterShutdown).EQS."y"
$     then
$         write sys$error "%SHUTDOWN-E-INVREQ, you may not specify both REMOVE_NODE and CLUSTER_SHUTDOWN"
$         goto AskOptions
$     endif
$ endif

$!
$! Reboot check...
$!
$ errors=0
$! TODO
$ if errors.EQ.0
$ then
$     write sys$output "%SHUTDOWN-I-CHECKOK, basic reboot consistency check completed"
$ else
$     write sys$error "%SHUTDOWN-E-NOREBOOT, the system will be unable to reboot"
$     write sys$error "%SHUTDOWN-E-NOREBOOT, correct above errors before shutting down the system"
$     exit
$ endif
$!
$ if f$extract(0,1,SaveFeedback).EQS."y"
$ then
$     write sys$output "%SHUTDOWN-I-SAVEFEED, saving feedback information from this boot..."
$! TODO
$     write sys$output "%SHUTDOWN-I-SAVEOK, feedback information saved"
$ endif

$BeginShutdown:
$!
$! Begin the shutdown process
$!
$ set noon
$ set terminal/nobroadcast OPA0:
$ write sys$output "%SHUTDOWN-I-BRDOPROFF, broadcasts to the operator have been disabled"
$ value = f$cvtime("+''Minutes':00.0", "ABSOLUTE")
$ define /system /exec shutdown$time "''value'"
$ Node = f$getsyi( "nodename" )
$ if Node.EQS."" then Node = "the system"
$ NextNotice = Minutes
$ OpTerm = 0
$ OpNet = 0
$ OpQues = 0
$ OpAuto = 0
$!

$TimeLoop:
$ if Minutes.LTE.NextNotice
$ then
$     Msg = "''Node' will shut down in ''Minutes' minutes for ''Reason'; back up ''Backup'. Please log off node ''Node'."
$     reply/all/bell/shutdown "''Msg'"
$     NextNotice = Minutes / 2
$ endif
$ if Minutes.LTE.6
$ then
$     if OpTerm.EQ.0
$     then
$         reply/enable
$         write sys$output "%SHUTDOWN-I-OPERATOR, this terminal is now an operator's console"
$         write sys$output "%SHUTDOWN-I-DISLOGINS, interactive logins will now be disabled"
$         set login/interactive=0
$         OpTerm = 1
$     endif
$ endif
$ if Minutes.LTE.NetMin
$ then
$     if OpNet.EQ.0
$     then
$         write sys$output "%SHUTDOWN-I-SHUTNET, the network will now be shut down"
$!TODO
$         OpNet = 1
$     endif
$ endif
$ if Minutes.LTE.QueMin
$ then
$     if OpQues.EQ.0
$     then
$         write sys$output "%SHUTDOWN-I-STOPQUEUES, all queues on this node will now be stopped"
$         define /user sys$output NULLA0:
$         define /user sys$error NULLA0:
$!TODO
$         set message/nofacility/noseverity/noidentification/notext
$         OpQues = 1
$         OpAuto = 1
$     endif
$ endif
$ if Minutes.LTE.AutoStart
$ then
$     if OpAuto.EQ.0
$     then
$         disable autostart /queues
$         OpAuto = 1
$     endif
$ endif
$ WaitTime = Minutes - NextNotice
$ if Minutes.GT.6
$ then
$     if WaitTime.GT.Minutes-6 then WaitTime = Minutes-6
$ endif
$ if WaitTime.GT.Minutes-NetMin then WaitTime = Minutes - NetMin
$ if WaitTime.GT.Minutes-QueMin then WaitTime = Minutes - QueMin
$ if WaitTime.GT.Minutes-AutoStart then WaitTime = Minutes - AutoStart
$ wait WaitTime
$ Minutes = Minutes - WaitTime
$ if Minutes>0 then goto TimeLoop

$!
$! Final shutdown
$!
$ if f$extract(0,1,SiteShutdown).EQ."y"
$ then
$     write sys$output "%SHUTDOWN-I-SITESHUT, the site-specific shutdown procedure will now be invoked"
$     @sys$manager:syshutdwn
$ endif

$! Build list of processes in our job
$ pid = f$getjpi( 0, "pid" )
$ pids = "|''pid'"
$pidloop:
$ pid = f$getjpi( pid, "owner" )
$ if pid .nes. "" 
$ then
$     pids = "''pids'|''pid'"
$     goto pidloop
$ endif
$ pids = "''pids'|"
$! Delete all other processes
$ reply/all/bell/shutdown "''Node' is shutting down now."
$ write sys$output "%SHUTDOWN-I-STOPUSER, all user processes will now be stopped"
$ 
$PidKillLoop:
$ pid = f$pid(context)
$ if pid.NES.""
$ then
$     if f$locate("|''pid'|",pids).EQ.f$length(pids)
$     then
$         pname = f$getjpi(pid,"PRCNAM")
$         stop/identification='pid
$     endif
$     goto PidKillLoop
$ endif

Now that we have our list of protected processes, we send our our final notice to any users who ignored our previous warnings and are still logged in. We notify the admin running the script that what we are doing now, and then we loop through all processes on the system. For each process, if its PID is not in our list, we kill it. We will discuss the STOP command in a future article.

$ write sys$output "%SHUTDOWN-I-REMOVE, all installed images will now be removed"
$!TODO
$ write sys$output "%SHUTDOWN-I-STOPCPU, all secondary processors will now be stopped"
$!TODO
$ reply/nolog
$ reply/disable
$ set message/nofacility/noseverity/noidentification/notext
$ value = ""
$ if f$extract(0,1,Restart).EQS."y" then value = "/restart"
$ run sys$system:opccrash 'value
$ write sys$output "%SHUTDOWN-F-OPCCRASH, the system could not be crashed"